3f144f57@news.povray.org...
> Do you have any sample-code of this? I'm struggling for this at the
moment,
> and rather working in the dark.

Try the code below. Left sphere is with subsurface scattering.
Note that it shows one problem I had with the ISS image when I used this on
the kid's arm, which is that the dark (densest) parts tend to be quite black
and do not react to radiosity. The only solution I found is by using
emission, which caused other problems and then I ran out of testing time.
It's also a problem with clouds, but it can be camouflaged by fog... I guess
that until we get real blurred transluscency there's no permanent
solution... unless I missed something obvious that is.

global_settings{
    assumed_gamma 1
    radiosity{media on}
}
camera {
  location  <0,1,-4>
  direction z
  right     x*image_width/image_height
  look_at   y
}
sphere{0,1
    texture{
        pigment{rgbf <1,0.6,0.2,1>}
        finish{ambient 0 diffuse 1 specular 0.2 roughness 1/200 }
    }
    hollow
    interior{
        media{
            scattering {1 rgb 4}
        }
    }
    translate y
    translate -x*1.1
}

sphere{0,1
    texture{
        pigment{rgb <1,0.6,0.2>}
        finish{ambient 0 diffuse 1 specular 0.2 roughness 1/200}
    }
    translate y
    translate x*1.1
}
plane{y,0 texture{pigment{rgb 1} finish{ambient 0 diffuse 1}}}
light_source {0  color rgb 1 translate <-1,1,1>*1000}


--
**********************
http://www.oyonale.com
**********************
- Graphic experiments
- POV-Ray and Poser computer images
- Posters

Post a reply to this message